@echo off

REM [2022/05/25] MOD 各フォルダパスを変数へ保存(OSで新しいパスができたときに対応しやすいように改造) -->

REM <11以降OneDrive使用でこのケースあり>
IF EXIST "%USERPROFILE%\OneDrive\デスクトップ\." SET desktop=%USERPROFILE%\OneDrive\デスクトップ
IF EXIST "%USERPROFILE%\OneDrive\デスクトップ\." SET programs=%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs
IF EXIST "%USERPROFILE%\OneDrive\デスクトップ\." SET startup=%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup
REM <10以降OneDrive使用>
IF EXIST "%USERPROFILE%\OneDrive\Desktop\." SET desktop=%USERPROFILE%\OneDrive\Desktop
IF EXIST "%USERPROFILE%\OneDrive\Desktop\." SET programs=%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs
IF EXIST "%USERPROFILE%\OneDrive\Desktop\." SET startup=%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup
REM <Vista/7/8/10/11>
IF EXIST "%USERPROFILE%\Desktop\." SET desktop=%USERPROFILE%\Desktop
IF EXIST "%USERPROFILE%\Desktop\." SET programs=%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs
IF EXIST "%USERPROFILE%\Desktop\." SET startup=%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup
REM <2000/XP>
IF EXIST "%USERPROFILE%\デスクトップ\." SET desktop=%USERPROFILE%\デスクトップ
IF EXIST "%USERPROFILE%\デスクトップ\." SET programs=%USERPROFILE%\スタート メニュー\プログラム
IF EXIST "%USERPROFILE%\デスクトップ\." SET startup=%USERPROFILE%\スタート メニュー\プログラム\スタートアップ

REM [2022/05/25] MOD <--

ECHO.
ECHO ###　NANS21V　セットアップ　インストール《前》処理　開始 ###
ECHO.

:INST
ECHO.
ECHO ■NANS21Vインストーラーをコピーします。
ECHO.
if not exist "C:\バックアップ\Install\." mkdir "C:\バックアップ\Install"
xcopy /EIYD "バックアップ\Install\*.msi" "C:\バックアップ\Install"

:KANRI
if not exist "Documents and Settings\NANS21\デスクトップ\NANS管理\." goto DB
ECHO.
ECHO ■NANS管理フォルダをコピーします。
ECHO.
REM [2011/12/20] ADD --> 改版を考慮し、ファイル名からバージョンを削除
if exist "%desktop%\NANS管理\マニュアル\NANS21V CSVファイル説明書_ver1.70.pdf" rename "%desktop%\NANS管理\マニュアル\NANS21V CSVファイル説明書_ver1.70.pdf" "NANS21V CSVファイル説明書.pdf"

if exist "%desktop%\NANS管理\マニュアル\NANS21V 記録公認申請用CSVデータ作成ソフト操作説明書_v1.1.pdf" rename "%desktop%\NANS管理\マニュアル\NANS21V 記録公認申請用CSVデータ作成ソフト操作説明書_v1.1.pdf" "NANS21V 記録公認申請用CSVデータ作成ソフト操作説明書.pdf"

if exist "%desktop%\NANS管理\マニュアル\NANS21V 賞状・証明書印刷説明書_ver1.71.pdf" rename "%desktop%\NANS管理\マニュアル\NANS21V 賞状・証明書印刷説明書_ver1.71.pdf" "NANS21V 賞状・証明書印刷説明書.pdf"

if exist "%desktop%\NANS管理\マニュアル\NANS21V 操作説明書_ver1.70.pdf" rename "%desktop%\NANS管理\マニュアル\NANS21V 操作説明書_ver1.70.pdf" "NANS21V 操作説明書.pdf"
REM [2011/12/20] ADD <--

REM [2023/03/07] 旧「NANSQandA」フォルダを削除 ADD -->
rd /s /q "%desktop%\NANS管理\\マニュアル\NANSQandA"
REM [2023/03/07] ADD <--

xcopy /EIYD "Documents and Settings\NANS21\デスクトップ\NANS管理" "%desktop%\NANS管理"

REM [2022/08/05] 「Web状況監視DB登録」フォルダを削除 ADD -->
rd /s /q "%desktop%\NANS管理\Web状況監視DB登録"
REM [2022/08/05] ADD <--
REM [2023/03/07] 「Web状況監視DB登録バッチファイル」を削除 ADD -->
del "%desktop%\NANS管理\スマートフォン向けDB登録\nans21vdbWEBADD.bat"
REM [2023/03/07] ADD <--

:DB
if not exist "バックアップ\*.ndb" goto BACKUP
ECHO.
ECHO ■初期データベースをコピーします。
ECHO.
xcopy /EIYD "バックアップ\*.ndb" "C:\バックアップ"

:BACKUP
if not exist "C:\ニシ･スポーツ\." goto END
ECHO.
ECHO ■既存設定ファイルを退避します。
ECHO.
xcopy /EIY "C:\ニシ･スポーツ\NANS21V\Settings" "C:\ニシ･スポーツ\NANS21V\$Settings.tmp"
REM xcopy /EIY "C:\ニシ･スポーツ\NANS21V\Templates" "C:\ニシ･スポーツ\NANS21V\$Templates.tmp"

:SETTIME
if not exist "ニシ･スポーツ\NANS21V\DB\settime.bat" goto END
ECHO.
ECHO ■時刻合わせバッチファイルをコピーします。
ECHO.
xcopy /EIYD "ニシ･スポーツ\NANS21V\DB\settime.bat" "C:\ニシ･スポーツ\NANS21V\DB"
xcopy /EIYD "Documents and Settings\NANS21\スタート メニュー\プログラム\スタートアップ\settime.lnk" "%startup%"

:END
ECHO.
ECHO ###　NANS21V　セットアップ　インストール《前》処理　終了 ###
ECHO.
ECHO エラーメッセージが出力されていないことをご確認ください。
ECHO (エラーが出力された場合はNISHIに問合せください。)
ECHO.
PAUSE
